home *** CD-ROM | disk | FTP | other *** search
/ Floppyshop 2 / Floppyshop - 2.zip / Floppyshop - 2.iso / art&graf.ix / art-0039 / spr_des / source / spr_des2.a68 < prev    next >
Text File  |  1997-04-16  |  27KB  |  972 lines
  1.       ORG   0
  2. * Source code to GFA basic, SPRITE DESIGNER
  3. * File: SPR_DES2.A68
  4. * How to use:
  5. *  Poke.B start+0,mode     0-19
  6. *  Poke.B start+1,x        0-31
  7. *  Poke.B start+2,y        0-31
  8. *  Poke.B start+3,color    0-15
  9. *  Poke.B start+4,x_to     0-31
  10. *  Poke.B start+5,y_to     0-31
  11. *  Poke.B start+6,img1     0-15   (image to be edit)
  12. *  Poke.B start+7,img1     0-15   use when Swap Images&Copy Images
  13. *  Poke.W start+8,spritex  0-350
  14. *  Poke.W start+10,spritey 0-230
  15. *  Poke.L start+14,phys          physical screen
  16. *  Poke.L start+18,background    background screen
  17. *  Poke.L start+22,image ptr     ptr to 16 images (512*16 bytes)
  18. *  Call start+30
  19. * Mode:
  20. *   0: Plot x,y,color
  21. *   1: Line x,y,x_to,y_to,color
  22. *   2: Fill x,y,color
  23. *   3: Rotate Left
  24. *   4: Rotate Right
  25. *   5: Rotate Up
  26. *   6: Rotate Down
  27. *   7: Mirror
  28. *   8: Up&Down
  29. *   9: Turn 90'
  30. *  10: Turn 270'
  31. *  11: Clear
  32. *  12: Copy Phys to Background
  33. *  13: Copy Background to Phys (scr3 to scr1&scr2)
  34. *  14: Show sprite
  35. *  15: Move sprite
  36. *  16: Hide sprite
  37. *  17: Swap Images
  38. *  18: Copy Images
  39. *  19: Put image to board
  40. *
  41. ainit equ   $a000
  42. aput  equ   $a001
  43. aget  equ   $a002
  44. abox  equ   $a005
  45. ashow equ   $a009
  46. ahide equ   $a00a
  47. *
  48. mode     equ   0
  49. x1       equ   1
  50. y1       equ   2
  51. color    equ   3
  52. x2       equ   4
  53. y2       equ   5
  54. img1     equ   6
  55. img2     equ   7
  56. sprx     equ   8
  57. spry     equ  10
  58. sprimg   equ  12
  59. scr1     equ  14
  60. scr2     equ  18
  61. imgptr   equ  22
  62. *
  63. var   ds.b  30
  64. *
  65. * start of code...
  66. *
  67. * Initialize & Get address to routine
  68.    lea      var(pc),a3
  69.    dc.w     ainit          ;init line-a
  70.    move.l   a0,a4          ;base address
  71.    move.l   8(a0),a5       ;intin-arrays
  72.    move.l   12(a0),a6      ;ptsin-arrays
  73.    dc.w     ahide          ;hide mouse
  74.    clr.w    $24(a4)        ;writing mode=replace
  75.    lea      fillpat(pc),a0 ;fill pattern
  76.    move.l   a0,$2e(a4)     ; =solid
  77.    move.w   #1,$32(a4)     ;one pattern mask
  78.    clr.w    $34(a4)        ;one color fill
  79.    clr.w    $36(a4)        ;no clipping
  80.    move.b   mode(a3),d0
  81.    tst.b    d0             ;plot?
  82.    beq      plot
  83.    cmp.b    #1,d0          ;line?
  84.    beq      line
  85.    cmp.b    #2,d0          ;fill?
  86.    beq      fill
  87.    cmp.b    #3,d0          ;rotate left?
  88.    beq      left
  89.    cmp.b    #4,d0          ;r. right?
  90.    beq      right
  91.    cmp.b    #5,d0          ;r. up?
  92.    beq      up
  93.    cmp.b    #6,d0          ;r. down?
  94.    beq      down
  95.    cmp.b    #7,d0          ;mirror?
  96.    beq      mirror
  97.    cmp.b    #8,d0          ;up&down?
  98.    beq      updown
  99.    cmp.b    #9,d0          ;turn 90' ?
  100.    beq      turn90
  101.    cmp.b    #10,d0         ;turn 270' ?
  102.    beq      turn270
  103.    cmp.b    #11,d0         ;clear?
  104.    beq      clear
  105.    cmp.b    #12,d0         ;copy phys to background?
  106.    beq      copy1
  107.    cmp.b    #13,d0         ;copy background to phys?
  108.    beq      copy2
  109.    cmp.b    #14,d0         ;Show sprite?
  110.    beq      showspr
  111.    cmp.b    #15,d0         ;Move sprite?
  112.    beq      movespr
  113.    cmp.b    #16,d0         ;Hide sprite?
  114.    beq      hidespr
  115.    cmp.b    #17,d0         ;swap images?
  116.    beq      swapimg
  117.    cmp.b    #18,d0         ;copy images?
  118.    beq      copyimg
  119.    cmp.b    #19,d0         ;put image to board?
  120.    beq      putimg
  121. *
  122. *
  123. exit move   #0,0(a5)
  124.    dc.w     ashow
  125.    rts                     'return to Basic
  126. *
  127. *  used by program
  128. * Get image from board (pos. 256,144)
  129. getimg move #9,d1
  130.    move.l   imgptr(a3),a0  ;ptr to 16 images
  131.    clr      d0
  132.    move.b   img1(a3),d0    ;edit image
  133.    lsl      d1,d0          ;each image 512 bytes
  134.    lea      0(a0,d0.w),a0  ;address to current image
  135.    move.l   scr1(a3),a1    ;physical screen
  136.    add.l    #23168,a1      ;pos. 256,144
  137.    move     #31,d0         ;32 lines
  138. getl move.l (a1)+,(a0)+    ;copy from screen to image
  139.    move.l   (a1)+,(a0)+
  140.    move.l   (a1)+,(a0)+
  141.    move.l   (a1)+,(a0)+
  142.    add.l    #144,a1        ;next line
  143.    dbf      d0,getl
  144.    rts
  145. *   used by program
  146. * Set color ,color in D2
  147. setcolor move.w d2,0(a5)
  148.    clr.l    $18(a4)
  149.    clr.l    $1c(a4)
  150.    btst     #0,d2
  151.    beq      bp0
  152.    move.w   #1,$18(a4)
  153. bp0   btst  #1,d2
  154.    beq      bp1
  155.    move.w   #1,$1a(a4)
  156. bp1   btst  #2,d2
  157.    beq      bp2
  158.    move.w   #1,$1c(a4)
  159. bp2   btst  #3,d2
  160.    beq      bp3
  161.    move.w   #1,$1e(a4)
  162. bp3   rts
  163. *
  164. * (used by fill,rotate...)
  165. * Get a Point from screen (looking in small box)
  166. * In: D0=x D1=y  Out:D3=color
  167. point movem.l  d0/d1/d2,-(a7)
  168.    add      #256,d0
  169.    add      #144,d1
  170.    move     d0,0(a6)
  171.    move     d1,2(a6)
  172.    dc.w     aget
  173.    move     d0,d3
  174.    movem.l   (a7)+,d0/d1/d2
  175.    rts
  176. * 
  177. * Plot a point: Big Point & Small Point
  178. plot clr.w  d0
  179.    clr.w    d1
  180.    move.b   x1(a3),d0
  181.    move.b   y1(a3),d1
  182.    move.b   color(a3),d2
  183.    bsr      setcolor
  184.    bsr      plot0
  185.    bsr      getimg      ;new image
  186.    bra      exit
  187. *
  188. * Plot0 (used by plot,line,fill...)
  189. * d0=x,d1=y (color is set!)
  190. plot0 movem.l   d0/d1/d2/d3/d4,-(a7)
  191. *plot on small board
  192.    move.w   d0,d3          ;save x&y
  193.    move.w   d1,d4
  194.    add.w    #256,d0
  195.    add.w    #144,d1
  196.    move.w   d0,0(a6)
  197.    move.w   d1,2(a6)
  198.    dc.w     aput           ;plot x+256,y+144
  199. *plot on big board  box 6x+1,6y+1,6x+5,6y+5
  200.    mulu     #6,d3
  201.    mulu     #6,d4
  202.    addq.w   #1,d3
  203.    addq.w   #1,d4
  204.    move.w   d3,$26(a4)     ;6*x+1
  205.    move.w   d4,$28(a4)     ;6*y+1
  206.    addq.w   #4,d3
  207.    addq.w   #4,d4
  208.    move.w   d3,$2a(a4)     ;6*x+5
  209.    move.w   d4,$2c(a4)     ;6*y+5
  210.    dc.w     abox           ;filled rectangle
  211.    movem.l  (a7)+,d0/d1/d2/d3/d4
  212.    rts
  213. *
  214. * Line
  215. *
  216. line  move.b   color(a3),d2
  217.    bsr      setcolor
  218.    lea      local(pc),a0
  219.    clr.l    d0
  220.    clr.l    d1
  221.    clr.l    d2
  222.    clr.l    d3
  223.    move.b   x1(a3),d0             ;x1
  224.    move.b   y1(a3),d1             ;y1
  225.    move.b   x2(a3),d2            ;x2
  226.    move.b   y2(a3),d3            ;y2
  227.    move     d2,d7
  228.    sub      d0,d7
  229.    move     d7,dx(a0)            ;dx=x2-x1
  230.    move     #1,sdx(a0)           ;count sgn(dx) & abs(dx)...
  231.    tst      d7
  232.    bpl      dxplus
  233.    neg      d7
  234.    move     #$ffff,sdx(a0)
  235. dxplus   move  d7,adx(a0)
  236.    move     d3,d7
  237.    sub      d1,d7
  238.    move     d7,dy(a0)            ;dy=y2-y1
  239.    move     #1,sdy(a0)           ;count sgn(dy) & abs(dy)...
  240.    tst      d7
  241.    bpl      dyplus
  242.    neg      d7
  243.    move     #$ffff,sdy(a0)
  244. dyplus   move  d7,ady(a0)
  245.    cmp      adx(a0),d7           ;abs(dx)=abs(dy)?
  246.    bne      dynodx               ;no
  247.    move     sdx(a0),d2           ;xstep= -1,0 or +1
  248.    swap     d2
  249.    move     sdy(a0),d3           ;ystep= -1,0 or +1
  250.    swap     d3
  251.    bra      draw
  252. dynodx   bge   dybigdx           ;abs(dy)>=abs(dx)?
  253.    move     adx(a0),d7
  254.    move     sdx(a0),d2           ;xstep= -1,0 or +1
  255.    swap     d2
  256.    move     ady(a0),d3
  257.    swap     d3
  258.    divu     d7,d3                ;ystep= abs(dy)/abs(dx) ( *sgn(dy) )
  259.    and.l    #$ffff,d3
  260.    tst      sdy(a0)
  261.    bpl      draw
  262.    neg.l    d3
  263.    bra      draw
  264. dybigdx  move  ady(a0),d7
  265.    move     sdy(a0),d3           ;ystep= -1,0 or +1
  266.    swap     d3
  267.    move     adx(a0),d2           ;xstep= abs(dx)/abs(dy) ( *sgn(dx) )
  268.    swap     d2
  269.    divu     d7,d2
  270.    and.l    #$ffff,d2
  271.    tst      sdx(a0)
  272.    bpl      draw
  273.    neg.l    d2
  274. draw     swap  d0
  275.    swap     d1
  276.    move     #$8000,d0
  277.    move     #$8000,d1
  278.    swap     d0
  279.    swap     d1
  280. lloop    bsr   plot0
  281.    swap     d0
  282.    swap     d1
  283.    add.l    d2,d0
  284.    add.l    d3,d1
  285.    swap     d0
  286.    swap     d1
  287.    dbf      d7,lloop
  288.    bsr      getimg      ;update image
  289.    bra      exit
  290. *
  291. * Fill
  292. fill     move.b   color(a3),d2
  293.    clr      d0
  294.    clr      d1
  295.    move.b   x1(a3),d0
  296.    move.b   y1(a3),d1
  297.    bsr      setcolor
  298.    bsr      point       ;color at x,y in D3
  299.    move     d3,d4
  300.    cmp.b    d2,d4       ;fill color=background color?
  301.    beq      fillend
  302.    bsr      fill0
  303. fillend bsr getimg      ;update image
  304.    bra      exit
  305. fill0    bsr   point
  306.    cmp.b    d3,d4       ;another color than background?
  307.    bne      noysub      ;yes  (exit)
  308.    bsr      plot0
  309.    cmp      #30,d0      ;x>30?
  310.    bhi      noxadd      ;yes
  311.    addq     #1,d0       ;try fill x+1,y
  312.    bsr      fill0
  313.    subq     #1,d0
  314. noxadd   cmp   #30,d1   ;y>30?
  315.    bhi      noyadd      ;yes
  316.    addq     #1,d1       ;try fill x,y+1
  317.    bsr      fill0
  318.    subq     #1,d1
  319. noyadd   tst   d0       ;x=0?
  320.    beq      noxsub      ;yes
  321.    subq     #1,d0       ;try fill x-1,y
  322.    bsr      fill0
  323.    addq     #1,d0
  324. noxsub   tst   d1       ;y=1?
  325.    beq      noysub      ;yes
  326.    subq     #1,d1       ;try fill x,y-1
  327.    bsr      fill0
  328.    addq     #1,d1
  329. noysub   rts
  330. *
  331. * Rotate Left
  332. left  move     #31,d1   ;y=31 to 0
  333. rotly clr      d0       ;x=0 to 30
  334. rotlx addq     #1,d0    ;get color from x+1,y
  335.       bsr      point
  336.       subq     #1,d0
  337.       move     d3,d2    ;and plot it at x,y
  338.       bsr      setcolor
  339.       bsr      plot0
  340.       addq     #1,d0
  341.       cmp      #31,d0
  342.       bne      rotlx    ;next x
  343.       clr      d2
  344.       bsr      setcolor
  345.       bsr      plot0    ;rotate in color 0
  346.       dbf      d1,rotly ;next y
  347.       bsr      getimg   ;update image
  348.       bra      exit
  349. *
  350. * Rotate Right
  351. right move     #31,d1   ;y=31 to 0
  352. rotry move     #31,d0   ;x=31 to 1
  353. rotrx subq     #1,d0    ;get color from x-1,y
  354.       bsr      point
  355.       addq     #1,d0
  356.       move     d3,d2    ;and plot it at x,y
  357.       bsr      setcolor
  358.       bsr      plot0
  359.       subq     #1,d0
  360.       tst      d0
  361.       bne      rotrx    ;next x
  362.       clr      d2
  363.       bsr      setcolor
  364.       bsr      plot0    ;rotate in color 0
  365.       dbf      d1,rotry ;next y
  366.       bsr      getimg   ;update image
  367.       bra      exit
  368. *
  369. * Rotate Up
  370. up    move     #31,d0   ;x=31 to 0
  371. rotux clr      d1       ;y=0 to 30
  372. rotuy addq     #1,d1    ;get color from x,y+1
  373.       bsr      point
  374.       subq     #1,d1
  375.       move     d3,d2    ;and plot it at x,y
  376.       bsr      setcolor
  377.       bsr      plot0
  378.       addq     #1,d1
  379.       cmp      #31,d1
  380.       bne      rotuy    ;next y
  381.       clr      d2
  382.       bsr      setcolor
  383.       bsr      plot0    ;rotate in color 0
  384.       dbf      d0,rotux ;next x
  385.       bsr      getimg   ;update image
  386.       bra      exit
  387. *
  388. * Rotate Down
  389. down  move     #31,d0   ;x=31 to 0
  390. rotdx move     #31,d1   ;y=31 to 1
  391. rotdy subq     #1,d1    ;get color from x,y-1
  392.       bsr      point
  393.       addq     #1,d1
  394.       move     d3,d2    ;and plot it at x,y
  395.       bsr      setcolor
  396.       bsr      plot0
  397.       subq     #1,d1
  398.       tst      d1
  399.       bne      rotdy    ;next y
  400.       clr      d2
  401.       bsr      setcolor
  402.       bsr      plot0    ;rotate in color 0
  403.       dbf      d0,rotdx ;next x
  404.       bsr      getimg   ;update image
  405.       bra      exit
  406. *
  407. * Mirror
  408. mirror move    #31,d1   ;y=31 to 0
  409. miry  move     #15,d0   ;x=15 to 0
  410. mirx  bsr      point    ;color at x,y
  411.       move     d3,d4
  412.       eor      #31,d0
  413.       bsr      point    ;color at 31-x,y
  414.       move     d3,d5
  415.       move     d4,d2
  416.       bsr      setcolor ;first color
  417.       bsr      plot0    ; plot at 31-x,y
  418.       eor      #31,d0
  419.       move     d5,d2
  420.       bsr      setcolor ;second color
  421.       bsr      plot0    ; plot at x,y
  422.       dbf      d0,mirx  ;next x
  423.       dbf      d1,miry  ;next y
  424.       bsr      getimg   ;update image
  425.       bra      exit
  426. *
  427. * Up & Down
  428. updown move    #31,d0   ;x=31 to 0
  429. updox move     #15,d1   ;y=15 to 0
  430. updoy bsr      point    ;color at x,y
  431.       move     d3,d4
  432.       eor      #31,d1
  433.       bsr      point    ;color at x,31-y
  434.       move     d3,d5
  435.       move     d4,d2
  436.       bsr      setcolor ;first color
  437.       bsr      plot0    ; plot at x,31-y
  438.       eor      #31,d1
  439.       move     d5,d2
  440.       bsr      setcolor ;second color
  441.       bsr      plot0    ; plot at x,y
  442.       dbf      d1,updoy
  443.       dbf      d0,updox
  444.       bsr      getimg   ;update image
  445.       bra      exit
  446. *
  447. * Turn 90'
  448. turn90   clr   d1
  449. t90y  clr      d0
  450. t90x  bsr      point
  451.       move     d3,d4
  452.       move     d0,d7
  453.       move     d1,d0
  454.       move     d7,d1
  455.       eor      #31,d0
  456.       bsr      point
  457.       move     d3,d2
  458.       eor      #31,d0
  459.       move     d0,d7
  460.       move     d1,d0
  461.       move     d7,d1
  462.       bsr      setcolor
  463.       bsr      plot0
  464.       eor      #31,d0
  465.       eor      #31,d1
  466.       bsr      point
  467.       move     d3,d2
  468.       move     d0,d7
  469.       move     d1,d0
  470.       move     d7,d1
  471.       eor      #31,d1
  472.       bsr      setcolor
  473.       bsr      plot0
  474.       eor      #31,d0
  475.       eor      #31,d1
  476.       bsr      point
  477.       move     d3,d2
  478.       move     d0,d7
  479.       move     d1,d0
  480.       move     d7,d1
  481.       eor      #31,d1
  482.       bsr      setcolor
  483.       bsr      plot0
  484.       move     d0,d7
  485.       move     d1,d0
  486.       move     d7,d1
  487.       eor      #31,d0
  488.       move     d4,d2
  489.       bsr      setcolor
  490.       bsr      plot0
  491.       move     d0,d7
  492.       move     d1,d0
  493.       move     d7,d1
  494.       eor      #31,d0
  495.       addq     #1,d0
  496.       cmp      #16,d0
  497.       bne      t90x
  498.       addq     #1,d1
  499.       cmp      #16,d1
  500.       bne      t90y
  501.       bsr      getimg   ;update image
  502.       bra      exit
  503. *
  504. * Turn 270'
  505. turn270 clr    d1
  506. t270y clr      d0
  507. t270x bsr      point
  508.       move     d3,d4
  509.       move     d0,d7
  510.       move     d1,d0
  511.       move     d7,d1
  512.       eor      #31,d1
  513.       bsr      point
  514.       move     d3,d2
  515.       move     d0,d7
  516.       move     d1,d0
  517.       move     d7,d1
  518.       eor      #31,d0
  519.       bsr      setcolor
  520.       bsr      plot0
  521.       eor      #31,d0
  522.       eor      #31,d1
  523.       bsr      point
  524.       move     d3,d2
  525.       eor      #31,d1
  526.       move     d0,d7
  527.       move     d1,d0
  528.       move     d7,d1
  529.       bsr      setcolor
  530.       bsr      plot0
  531.       eor      #31,d0
  532.       eor      #31,d1
  533.       bsr      point
  534.       move     d3,d2
  535.       eor      #31,d1
  536.       move     d0,d7
  537.       move     d1,d0
  538.       move     d7,d1
  539.       bsr      setcolor
  540.       bsr      plot0
  541.       eor      #31,d0
  542.       move     d0,d7
  543.       move     d1,d0
  544.       move     d7,d1
  545.       move     d4,d2
  546.       bsr      setcolor
  547.       bsr      plot0
  548.       eor      #31,d0
  549.       move     d0,d7
  550.       move     d1,d0
  551.       move     d7,d1
  552.       addq     #1,d0
  553.       cmp      #16,d0
  554.       bne      t270x
  555.       addq     #1,d1
  556.       cmp      #16,d1
  557.       bne      t270y
  558.       bsr      getimg      ;update image
  559.       bra      exit
  560. *
  561. * Clear
  562. clear clr      d2
  563.       bsr      setcolor
  564.       move     #31,d1   ;y=31 to 0
  565. clry  move     #31,d0   ;x=31 to 0
  566. clrx  bsr      plot0    ;clear
  567.       dbf      d0,clrx
  568.       dbf      d1,clry
  569.       bsr      getimg   ;update image
  570.       bra      exit
  571. *
  572. * Put image (move image from memory to big board)
  573. putimg move    #9,d1
  574.       move.l   imgptr(a3),a0     ;address to 16 images
  575.       clr      d0
  576.       move.b   img1(a3),d0       ;image to be putted
  577.       lsl      d1,d0             ;each image 512 bytes
  578.       lea      0(a0,d0.w),a0     ;address to current image
  579.       move.l   scr1(a3),a1       ;physbase
  580.       add.l    #23168,a1         ;pos 256,144
  581.       move     #31,d0            ;32 lines
  582. putl  move.l   (a0)+,(a1)+       ;copy from memory to screen
  583.       move.l   (a0)+,(a1)+
  584.       move.l   (a0)+,(a1)+
  585.       move.l   (a0)+,(a1)+
  586.       add.l    #144,a1           ;next line
  587.       dbf      d0,putl
  588.       move     #31,d0            ;x=31 to 0
  589. putlx move     #31,d1            ;y=31 to 0
  590. putly bsr      point             ;get color value to d3 (from little board)
  591.       move     d3,d2
  592.       bsr      setcolor
  593.       bsr      plot0             ;plot on big board (& little board)
  594.       dbf      d1,putly
  595.       dbf      d0,putlx
  596.       bra      exit
  597. *
  598. * Copy physbase to background
  599. copy1 move.l scr1(a3),a0         ;physbase
  600.       move.l   scr2(a3),a1       ;background
  601.       move     #8000,d0          ;8000 long words
  602. copy  move.l   (a0)+,(a1)+       ;copy
  603.       dbf      d0,copy
  604.       bra      exit
  605. *
  606. * Copy background to physbase
  607. copy2 move.l   scr2(a3),a0
  608.       move.l   scr1(a3),a1
  609.       move     #8000,d0
  610.       bra      copy
  611. *
  612. * Copy images img1 to img2
  613. copyimg move   #9,d1
  614.       move.l   imgptr(a3),a0  :\start of image area
  615.       clr      d0
  616.       move.b   img1(a3),d0
  617.       lsl      d1,d0          :\each image 512 bytes
  618.       add.l    d0,a0          :\ptr to image 1 
  619.       move.l   imgptr(a3),a1
  620.       clr      d0
  621.       move.b   img2(a3),d0
  622.       lsl      d1,d0
  623.       add.l    d0,a1          :\ptr to image 2
  624.       move     #31,d0         :\32 lines
  625. copyl move.l   (a0)+,(a1)+
  626.       move.l   (a0)+,(a1)+
  627.       move.l   (a0)+,(a1)+
  628.       move.l   (a0)+,(a1)+
  629.       dbf      d0,copyl
  630.       bra      exit
  631. *
  632. * Swap images
  633. swapimg move   #9,d1
  634.       move.l   imgptr(a3),a0  :\start of image area
  635.       clr      d0
  636.       move.b   img1(a3),d0
  637.       lsl      d1,d0          :\each image 512 bytes
  638.       add.l    d0,a0          :\ptr to image 1
  639.       move.l   imgptr(a3),a1
  640.       clr      d0
  641.       move.b   img2(a3),d0
  642.       lsl      d1,d0
  643.       add.l    d0,a1          :\ptr to image 2
  644.       move     #31,d0         :\32 lines
  645. swapl move.l   0(a0),d1
  646.       move.l   4(a0),d2
  647.       move.l   8(a0),d3
  648.       move.l   12(a0),d4
  649.       move.l   0(a1),(a0)+
  650.       move.l   4(a1),(a0)+
  651.       move.l   8(a1),(a0)+
  652.       move.l   12(a1),(a0)+
  653.       move.l   d1,(a1)+
  654.       move.l   d2,(a1)+
  655.       move.l   d3,(a1)+
  656.       move.l   d4,(a1)+
  657.       dbf      d0,swapl
  658.       bra      exit
  659. *
  660. * Show sprite
  661. showspr bsr    dospr
  662.         bra    exit
  663. *
  664. * Move sprite
  665. movespr bsr    unspr
  666.       bsr      dospr
  667.       bra      exit
  668. *
  669. * Hide sprite
  670. hidespr bsr    unspr
  671.       bra      exit
  672. *
  673. * Erase sprite (used by program)
  674. unspr lea      local(pc),a2
  675.       move.l   sproff(a2),d0  :\offset to screen
  676.       move.l   scr1(a3),a0    :\physbase
  677.       move.l   scr2(a3),a1    :\background
  678.       add.l    d0,a0
  679.       add.l    d0,a1
  680.       move     sprheight(a2),d1 :\visible sprite height-1
  681.       move     sprwidth(a2),d0  :\x-words saved
  682.       cmp      #1,d0          :\16 pixel saved?
  683.       beq      un16
  684.       cmp      #2,d0          :\32 pixel saved?
  685.       beq      un32           :\ else 48 pixel saved!
  686. un48  move.l  (a1)+,(a0)+     :\copy 48 pixel*4 planes=24 bytes
  687.       move.l   (a1)+,(a0)+
  688.       move.l   (a1)+,(a0)+
  689.       move.l   (a1)+,(a0)+
  690.       move.l   (a1)+,(a0)+
  691.       move.l   (a1)+,(a0)+
  692.       add.l    #136,a0        :\next line
  693.       add.l    #136,a1
  694.       dbf      d1,un48
  695.       rts
  696. un32  move.l   (a1)+,(a0)+    :\copy 32 pixel*4 planes=16 bytes
  697.       move.l   (a1)+,(a0)+
  698.       move.l   (a1)+,(a0)+
  699.       move.l   (a1)+,(a0)+
  700.       add.l    #144,a0        :\next line
  701.       add.l    #144,a1
  702.       dbf      d1,un32
  703.       rts
  704. un16  move.l   (a1)+,(a0)+    :\copy 16pixel*4 planes=8 bytes
  705.       move.l   (a1)+,(a0)+
  706.       add.l    #152,a0        :\next line
  707.       add.l    #152,a1
  708.       dbf      d1,un16
  709.       rts
  710. *
  711. * Draw sprite (used by program)
  712. dospr lea      local(pc),a2
  713.       move     #9,d1
  714.       move.l   imgptr(a3),a1
  715.       clr      d0
  716.       move.b   sprimg(a3),d0
  717.       lsl      d1,d0
  718.       add.l    d0,a1          :\image pointer
  719.       move     sprx(a3),d0    :\sprite-x
  720.       move     spry(a3),d1    :\sprite-y
  721.       cmp      #350,d0        :\x out of range?  (0-350)
  722.       bhi      doexit
  723.       cmp      #230,d1        :\y out of range?  (0-230)
  724.       bhi      doexit
  725. *
  726.       move.l   #0,a0          :\offset on screen (inc. later)
  727. *
  728.       cmp      #30,d1         :\sprite at top?
  729.       bhi      donotop
  730.       move     d1,d2          :\#lines-1=y0
  731.       eor      #31,d1         :\start=31-y0
  732.       bra      doyok
  733. donotop cmp    #199,d1        :\sprite in middle?
  734.       bhi      donomiddle
  735.       move     d1,d7          :\screen=y0-31
  736.       sub      #31,d7
  737.       mulu     #160,d7
  738.       add.w    d7,a0          :\inc. screen offset
  739.       clr      d1             :\start=0
  740.       move     #31,d2         :\#lines-1=31
  741.       bra      doyok
  742. donomiddle move d1,d7         :\screen=y0-31
  743.       sub      #31,d7
  744.       mulu     #160,d7
  745.       add.w    d7,a0          :\inc. screen offset
  746.       move     d1,d2          :\#lines-1=31-(y0-199)
  747.       sub      #199,d2
  748.       eor      #31,d2
  749.       clr      d1             :\start=0
  750. doyok move     d2,sprheight(a2) :\save height-1
  751.       lsl      #4,d1          :\adjust image ptr
  752.       lea      0(a1,d1.w),a1   :\ to current sprite height
  753.       cmp      #14,d0         :\sprite on left side?
  754.       bhi      nol1
  755. *Sprite on the left side (0-50%)
  756.       move     #1,sprwidth(a2)       :\save x-words (16 pixel)
  757.       move.l   a0,sproff(a2)  :\save screen offset
  758.       add.l    scr1(a3),a0    :\physbase+offset
  759.       and      #15,d0         :\x MOD 15=rotations
  760.       addq     #1,d0          :\at least one pixel visible
  761.       addq.l   #8,a1          :\skip left side of sprite
  762. dloop1 bsr     pixleft
  763.       add.l    #160,a0        :\next line
  764.       add.l    #8,a1          :\skip left side
  765.       dbf      d2,dloop1
  766.       bra      doexit
  767. nol1  cmp      #30,d0         :\sprite on left side?
  768.       bhi      nol2
  769. *Sprite on the left side (50-100%)
  770.       move     #2,sprwidth(a2)       :\save x-words (32 pixel)
  771.       move.l   a0,sproff(a2)       :\save screen offset
  772.       add.l    scr1(a3),a0          :\physbase+offset
  773.       sub      #15,d0         :\begin x=0
  774.       and      #15,d0         :\rotations
  775. dloop2 bsr     pixleft
  776.       bsr      pix16
  777.       add.l    #160,a0        :\next line
  778.       dbf      d2,dloop2
  779.       bra      doexit
  780. nol2  cmp      #319,d0        :\sprite in the middle (x)
  781.       bhi      nocenter
  782. *Sprite in the middle
  783.       move     #3,sprwidth(a2)       :\save x-words (48 pixel)
  784.       sub      #31,d0         :\begin x=0
  785.       move     d0,d3
  786.       and      #15,d0         :\rotations
  787.       lsr      #4,d3          :\x-byte=4*(x DIV 16)
  788.       lsl      #3,d3
  789.       lea      0(a0,d3.w),a0  :\inc. screen offset
  790.       move.l   a0,sproff(a2)  :\save screen offset
  791.       add.l    scr1(a3),a0    :\physbase+offset
  792. dloop3 bsr     pix16
  793.       add.l    #8,a0          :\next 16 pixel
  794.       bsr      pix16
  795.       add.l    #152,a0        :\next line
  796.       dbf      d2,dloop3
  797.       bra      doexit
  798. nocenter cmp   #335,d0        :\sprite on right side?
  799.       bhi      doright2
  800. *Sprite on the right side (50-100%)
  801.       move     #2,sprwidth(a2)       :\save x-words (32 pixel)
  802.       add.l    #144,a0        :\inc. screen offset
  803.       move.l   a0,sproff(a2)  :\save screen offset
  804.       add.l    scr1(a3),a0    :\physbase+offset
  805.       sub      #320,d0        :\begin x=0
  806.       and      #15,d0         :\rotations
  807.       addq     #1,d0          :\at least one pixel visible
  808. dloop4 bsr     pix16
  809.       add.l    #8,a0          :\next 16 pixel
  810.       bsr      pixright
  811.       add.l    #152,a0        :\next line
  812.       dbf      d2,dloop4
  813.       bra      doexit
  814. *Sprite on the right side (0-50%)
  815. doright2 move  #1,sprwidth(a2)      :\save x-words (16 pixel)
  816.       add.l    #152,a0        :\inc. screen offset
  817.       move.l   a0,sproff(a2)      :\save screen offset
  818.       add.l    scr1(a3),a0          :\phybase+offset
  819.       sub      #336,d0        :\begin x=0
  820.       and      #15,d0         :\rotations
  821.       addq     #1,d0          :\at least one pixel visible
  822. dloop5 bsr     pixright
  823.       add.l    #8,a1          :\skip right side on sprite
  824.       add.l    #160,a0        :\next line
  825.       dbf      d2,dloop5
  826. doexit rts
  827. *
  828. pix16 MOVE (A1)+,D4           :\get sprite data
  829.    MOVE   (A1)+,D5            :\4planes a 16 pixel
  830.    MOVE   (A1)+,D6
  831.    MOVE   (A1)+,D7
  832.    SWAP   D4                  :\sprite in high word
  833.    SWAP   D5
  834.    SWAP   D6
  835.    SWAP   D7
  836.    CLR    D4                  :\clear low word
  837.    CLR    D5
  838.    CLR    D6
  839.    CLR    D7
  840.    LSR.L  D0,D4               :\rotate D0 times
  841.    LSR.L  D0,D5
  842.    LSR.L  D0,D6
  843.    LSR.L  D0,D7
  844. *make a mask (color 0=transparent)
  845.    MOVE.L D4,D3
  846.    OR.L   D5,D3
  847.    OR.L   D6,D3
  848.    OR.L   D7,D3
  849. *mask sprite data
  850.    AND.L  D3,D4
  851.    AND.L  D3,D5
  852.    AND.L  D3,D6
  853.    AND.L  D3,D7
  854. *mask screen
  855.    NOT.L  D3
  856.    AND    D3,$8(A0)
  857.    AND    D3,$A(A0)
  858.    AND    D3,$C(A0)
  859.    AND    D3,$E(A0)
  860.    SWAP   D3
  861.    AND    D3,$0(A0)
  862.    AND    D3,$2(A0)
  863.    AND    D3,$4(A0)
  864.    AND    D3,$6(A0)
  865.    SWAP   D3
  866. *add screen with sprite
  867.    ADD    D4,$8(A0)
  868.    ADD    D5,$A(A0)
  869.    ADD    D6,$C(A0)
  870.    ADD    D7,$E(A0)
  871.    SWAP   D4
  872.    SWAP   D5
  873.    SWAP   D6
  874.    SWAP   D7
  875.    ADD    D4,$0(A0)
  876.    ADD    D5,$2(A0)
  877.    ADD    D6,$4(A0)
  878.    ADD    D7,$6(A0)
  879.    rts
  880. *
  881. pixleft MOVE (A1)+,D4          :\get sprite data
  882.    MOVE   (A1)+,D5             :\4planes a 16 pixel
  883.    MOVE   (A1)+,D6
  884.    MOVE   (A1)+,D7
  885.    SWAP   D4                   :\sprite in high word
  886.    SWAP   D5
  887.    SWAP   D6
  888.    SWAP   D7
  889.    CLR    D4                   :\clear low word
  890.    CLR    D5
  891.    CLR    D6
  892.    CLR    D7
  893.    LSR.L  D0,D4                :\rotate D0 times
  894.    LSR.L  D0,D5
  895.    LSR.L  D0,D6
  896.    LSR.L  D0,D7
  897. *make a mask (color 0=transparent)
  898.    MOVE   D4,D3
  899.    OR     D5,D3
  900.    OR     D6,D3
  901.    OR     D7,D3
  902. *mask sprite data(uses only bit0-15)
  903.    AND    D3,D4
  904.    AND    D3,D5
  905.    AND    D3,D6
  906.    AND    D3,D7
  907. *mask screen
  908.    NOT    D3
  909.    AND    D3,$0(A0)
  910.    AND    D3,$2(A0)
  911.    AND    D3,$4(A0)
  912.    AND    D3,$6(A0)
  913. *add screen with sprite
  914.    ADD    D4,$0(A0)
  915.    ADD    D5,$2(A0)
  916.    ADD    D6,$4(A0)
  917.    ADD    D7,$6(A0)
  918.    rts
  919. *
  920. pixright MOVE (A1)+,D4       :\get sprite data
  921.    MOVE   (A1)+,D5           :\4planes a 16 pixel
  922.    MOVE   (A1)+,D6
  923.    MOVE   (A1)+,D7
  924.    SWAP   D4                 :\sprite in high word
  925.    SWAP   D5
  926.    SWAP   D6
  927.    SWAP   D7
  928.    LSR.L  D0,D4              :\rotate D0 times
  929.    LSR.L  D0,D5
  930.    LSR.L  D0,D6
  931.    LSR.L  D0,D7
  932.    SWAP   D4                 :\sprite in low word
  933.    SWAP   D5
  934.    SWAP   D6
  935.    SWAP   D7
  936. *make a mask (color 0=transparent)
  937.    MOVE   D4,D3
  938.    OR     D5,D3
  939.    OR     D6,D3
  940.    OR     D7,D3
  941. *mask sprite data
  942.    AND    D3,D4
  943.    AND    D3,D5
  944.    AND    D3,D6
  945.    AND    D3,D7
  946. *mask screen
  947.    NOT    D3
  948.    AND    D3,$0(A0)
  949.    AND    D3,$2(A0)
  950.    AND    D3,$4(A0)
  951.    AND    D3,$6(A0)
  952. *add screen with sprite
  953.    ADD    D4,$0(A0)
  954.    ADD    D5,$2(A0)
  955.    ADD    D6,$4(A0)
  956.    ADD    D7,$6(A0)
  957.    rts
  958. *
  959. fillpatt  dc.w  $ffff,$ffff
  960. local    ds.w   30
  961. dx    equ   0
  962. dy    equ   2
  963. sdx   equ   4
  964. sdy   equ   6
  965. adx   equ   8
  966. ady   equ   10
  967. sproff    equ  12
  968. sprwidth  equ  16
  969. sprheight equ  18
  970. *
  971.    end
  972.